/* Eratosthenes Sieve benchmark */

true    = 1
false    = 0
size    = 8190
sizepl    = 8191

flags    = $8000


    org $2000

;void wait(void)
;{
; unsigned char a=PEEK(tick);
; while (PEEK(tick)==a) { ; }
;}

.proc wait
    lda:cmp:req 20
    rts
.endp


main

;int main()
;{
;    unsigned int i, prime, k, count, iter;
    .var i, prime, k, count, iter .word
    
;    wait();
    wait

    mwa #0 $13

;    printf("10 iterations\n");

;    iter = 1;
    mwa #1 iter

;    while (iter <= 10) {
p0    .while .word iter <= #10    ;0

;        count = 0;
        mwa #0 count

;        i = 0;
        mwa #0 i

;        while (i <= size) {
p1        .while .word i <= #size        ;1

;            flags[i] = true;

            lda <flags
            clc
            adc i
            sta adr
            lda >flags
            adc i+1
            sta adr+1

            lda #true
            sta $ffff
        adr:    equ *-2
        
;            i++;
            inw i
;        }
        .endw

;        i = 0;
        mwa #0 i
        
;        while (i <= size) {
p2        .while .word i <= #size        ;2

;            if (flags[i]) {

            lda <flags
            clc
            adc i
            sta adr2
            lda >flags
            adc i+1
            sta adr2+1

            lda $ffff
        adr2:    equ *-2

            beq skip

;                prime = i + i + 3;
                lda i
                clc
                adc i
                sta prime
                lda i+1
                adc i+1
                sta prime+1

                lda prime
                clc
                adc #3
                sta prime
                scc
                inc prime+1                
                
;                k = i + prime;

                lda i
                clc
                adc prime
                sta k
                lda i+1
                adc prime+1
                sta k+1

;                while (k <= size) {
p3                .while .word k <= #size        ;3

;                    flags[k] = false;

                    lda <flags
                    clc
                    adc k
                    sta adr3
                    lda >flags
                    adc k+1
                    sta adr3+1

                    lda #false
                    sta $ffff
                adr3:    equ *-2

;                    k = k + prime;

                    lda k
                    clc
                    adc prime
                    sta k
                    lda k+1
                    adc prime+1
                    sta k+1

;                }
                .endw

;                count++;
                inw count

;            }
        skip:

;            i++;
            inw i

;        }
        .endw

;        iter++;

        inw iter

;    }
    .endw
    
;    printf("\n%d primes\n", count);
    
;    i=PEEK(tick)+PEEK(tack)*256;

;    printf("\n%d fps\n", i);
    
;    return 0;
;}

    mwa $13 $600
    mwa count $602

    mva #$80 712
    jmp *


    run main