Hi!

Laoo, on atariage forums you can read as below:

so, as You see there is other hardware solutions for Stereo-POKEY for 8-bit ATARI :)
I did't know about this solution, before I read those post on Atari Age forum.

The IRQ method, is probably don't work for the cartridge version of Stereo-Upgrade.
But as You notice before I think that the "IRQ" detection is the best way to detect the standard stereo upgrage (second POKEY located at D21x area)

on AtariAge forum, Raster show the own code for second Pokey detection:

pokey1 equ $d200
pokey2 equ $d210

STEREODETECTION
   lda pokey1+$09
   beq iss2  ;0 => last key L
;no last key L
   lda pokey2+$09
   beq issyes;0 on second POKEY KEY reg => stereo
issno
   lda #0
   rts
iss2
   ldy #7
iss3
   lda pokey2,y;POT regs
   bne issno   ;some one is not zero
   dey
   bpl iss3
issyes
   lda #1
   rts

and here is, my old stereo detect routine (based od IRQ), this procedure was published a long time ago in our "Barymag" magazine.

* -----------------------------
* |second POKEY detect routine|
* | answer in A register:     |
* |$00 - absent $80 - present |
* -----------------------------
* | code & idea: Seban/SLIGHT |
* |-+* (c) 1995,96 Slight! *+-|
* -----------------------------

st  sei
    inc $d40e
    lda #$03
    sta $d21f
    sta $d210
    ldx #$00
    stx $d211
    inx
    stx $d21e
    ldx $d40b
    bne *-3
    stx $d219
w   ldx $d40b
    bmi ext
    lda #$01
    bit $d20e
    bne w
ext lda $10
    sta $d20e
    dec $d40e
    cli
    txa
    rts

greetz
Seban/SLIGHT

You load SysInfo: it uses a yet different routine to detect the stereo. If it hangs too, or mono is detected, then your stereo upgrade is definitely incorrectly done (hardware-wise) or damaged.

http://drac030.krap.pl/si210.arc

if my routine just hung up... you have probably a hardware problem with your ATARI... this procedure can't hung up in well working computer. If the IRQ from POKEY comes the procedure leaves as soon the IRQ comes... if the IRQ not come this procedure wait for $80 value in the $d40b register. So there is no way to hung up in correctly working computer.

with greetings
Seban/SLIGHT

Hi!

Yes... Draco have right. Try to change "*" jump to label, for example:

    ldx $d40b
    bne *-3

 chagne to:

ww  ldx $d40b
    bne ww

grtx
Seban/SLIGHT

Hi!

hmmm.... it's strange. In standard Stereo Upgrade the IRQ line from second POKEY is not connected. The second POKEY has no chance to generate an IRQ. On this fact is based my Stereo detection routine. If the computer does't have stereo upgrade. The write to $d21e register is the same as writing to the $d20e register, beceuse the adress decoder in standard ATARI is simplified and the sixteen pokey registers are repeated into $d200-$d2ff area.  After the adding the second pokey, we must slightly modify the address decoder for both pokeys.

In standard ATARI when you write to $d21e register, this register write comes to firt POKEY. He can generate IRQ and if the detection routine detect an IRQ the proceduce exits with $00 status = NO SECOND POKEY DETECTED. If in your computer is second POKEY installed, then write to $d21e, not affect the first pokey, and the write goes to second POKEY and because the second POKEY can't generate and IRQ... the IRQ never comes, and the routine return with the $80 status =  SECOND POKEY DETECTED.

Please chceck connections in your ATARI, the 29th pin of second pokey must be NOT CONNECTED. Here is pinout of the POKEY:
http://atariki.krap.pl/index.php/Grafik … _POKEY.png

with regards
Seban/SLIGHT