Nie jesteś zalogowany. Proszę się zalogować lub zarejestrować.
65C816 XL OS v. 2.47 Nowa wersja alternatywnego systemu operacyjnego
Echa Revision 2025 Kilka interesujących produkcji dla różnych platform Atari.
atari.area w mediach społecznościowych Choć sercem naszej społeczności pozostaje forum, przypominamy, że jesteśmy również aktywni w mediach społecznościowych.
Lost World by Desire Nowe demo grupy Desire.
sio2flip - emulator peryferiów sio2flip umożliwia podłączenie Flippera Zero do Atari i korzystanie z plików ATR jako wirtualnych dyskietek.
atari.area forum » Różne » Prima Aprilis Compo 2025
Strony 1
Zaloguj się lub zarejestruj by napisać odpowiedź
Już za chwileczkę, już za momencik.
Proponuję zacząć w tym roku w piątek 28 III 18:00 CET (GMT+1) wieczorem, a zakończyć we wtorek 1 IV 2025 0:00 CEST (czyli GMT+2). To razem 77 godzin.
Zasady jak zwykle.
Jeszcze trzy tygodnie. Myślcie Panowie co by tu w tym roku jeszcze...!
"Myślcie Panowie co by tu w tym roku jeszcze...!"
Ministra d/s równości Cię zaaresztuje ... :D
Ja w swoich programach używam znaku równości tak często, jak to tyko możliwe :)
A jesteś też pop(p)ersem? :D
Chcesz wygonić z domu gości, puść im tylko znak równości ;)
Tylko jak piszę w BASIC-u :) A i to nie zawsze.
Jeszcze tylko tydzień pozostał do rozpoczęcia tegorocznej edycji.
Z małym poślizgiem, ale startujemy:
32700 REM Prima Aprilis Compo 2025
32701 REM by Mono32700 REM Prima Aprilis Compo 2025
32701 REM by Mono
32702 REM atari jest lepsze od zx trumny
0 GOSUB 32600
1 GOSUB 31100
2 GOSUB 31000
11111 END
31000 REM ...
31099 RETURN
31100 REM 31000 - LOADING SCREEN, INTRODUCTION
31101 E=24:L=E-1:W=100:DIM BE$(E):BE$="BOOT ERROR "
31102 DIM PA25$(E):PA25$="PRIMA APRILIS COMPO 2025":DIM X$(1)
31103 GRAPHICS 0:? BE$:FOR I=0 TO W:NEXT I
31104 ? CHR$(125);BE$:IF E=0 THEN W=W-1:IF W=0 THEN GOTO 31999
31105 LL=L*RND(0)+1:X$=PA25$(LL,LL):IF X$="*" THEN 31104
31106 BE$(LL,LL)=CHR$(128+ASC(PA25$(LL,LL)))
31107 PA25$(LL,LL)="*":E=E-1
31111 GOTO 31104
31999 RETURN
32000 REM 32000 - BLOK LINII DATA
32600 REM 32600 - BLOKI INICJACYJNE
32601 GRAPHICS 8:POKE 106,128:GRAPHICS 8:GRAPHICS 0:POKE 82,0
32699 RETURN
32700 REM ****************************
32701 REM * PRIMA APRILIS COMPO 2025 *
32702 REM ****************************
32703 REM BY MONO,PABLOZ,MAW
32704 REM ATARI JEST LEPSZE OD ZX TRUMNY
32705 REM JEDZIEMY OD KONCA BASICA PANOWIE(I PANIE)
32706 REM 32600 - REZERWACJA PAMIECI (WSPOLNA DLA WSZYSTKICH) - OBNIZ RAMTOP, ZAKLNIJ DUCHY
32707 REM 32000 - REZERWACJA BLOKU LINII DLA DATA
32708 REM 31100 - LOADING SCREEN, INTRODUCTION
32709 REM 31000 - ...
32766 REM NIE ZAPOMNIEC O POKE 82,0!!!
RUN( prace nad intro w toku :D )
//EDIT: Załącznik z kodowaniem WINDOWS, otwarcie: emulator, dodaj urządzenie - dysk H:, zamapuj folder z plikiem (koniecznie z długimi nazwami!), załaduj:
E."H6:PA2025_1330.LST"taka wstaweczka;)
Kod główny:
0 GOSUB 32600
1 GOSUB 31100
2 GOSUB 31000
11111 END
31000 E."H6:PA25_31000.LST"
31100 E."H6:PA25_31100.LST"
32000 E."H6:PA25_31200.LST":REM 32000 - BLOK LINII DATA
32600 REM 32600 - BLOKI INICJACYJNE
32601 GRAPHICS 8:POKE 106,128:GRAPHICS 8:GRAPHICS 0:POKE 82,0
32699 RETURN
32700 REM ****************************
32701 REM * PRIMA APRILIS COMPO 2025 *
32702 REM ****************************
32703 REM BY MONO,PABLOZ,MAW,BCA
32704 REM ATARI JEST LEPSZE OD ZX TRUMNY
32705 REM JEDZIEMY OD KONCA BASICA PANOWIE(I PANIE)
32706 REM 32600 - REZERWACJA PAMIECI (WSPOLNA DLA WSZYSTKICH) - OBNIZ RAMTOP, ZAKLNIJ DUCHY
32707 REM 32000 - REZERWACJA BLOKU LINII DLA DATA
32708 REM 31100 - LOADING SCREEN, INTRODUCTION
32709 REM 31000 - ...
32766 REM NIE ZAPOMNIEC O POKE 82,0!!!
RUNLinie 31000-31099:
31000 REM 31000 - LOADING SCREEN, INTRODUCTION
31001 REM pusto?
31099 RETURN Linie 31100-31999:
31100 REM 31100 - LOADING SCREEN, INTRODUCTION
31101 REM SOME INFO BEFORE DEMO MODE AND LOADING SCREEN BY MAW
31102 E=24:L=E-1:W=25:ED=52:DIM BE$(E):BE$="BOOT ERROR ":DIM PA25$(E):PA25$="PRIMA APRILIS COMPO 2025":POKE 82,2
31103 FOR I=0 TO W:? CHR$(125):? BE$:? "be patient...":SOUND 0,8,ED,10:ED=ED+(ED=52)*8-(ED=60)*8:NEXT I
31104 SOUND 0,12,ED,10:ED=ED+8:IF ED=68 THEN ED=52:REM BCA #ORYGINAL MOGL ZABIC PIA/KOREKTA MAW
31105 ? CHR$(125);BE$:IF E=0 THEN W=W-1:IF W=0 THEN POKE 54018,60:GOTO 31110
31106 LL=L*RND(0)+1:IF PA25$(LL,LL)="*" THEN 31104
31107 BE$(LL,LL)=CHR$(128+ASC(PA25$(LL,LL))):PA25$(LL,LL)="*":E=E-1:GOTO 31104
31110 ? CHR$(125):POKE 559,0:POKE 82,0:POSITION 0,5:FOR N=20 TO 23:? 312;N;"POKE 656,0:POKE 657,0:? ";CHR$(34);
31111 FOR I=0 TO 39
31112 Z0=124*RND(0):IF (Z0>26 AND Z0<35) THEN 31112
31113 Z0=Z0+INT(RND(0)*2)*128:SOUND 0,Z0,10,10:? CHR$(Z0);:NEXT I
31114 ? CHR$(34);";:RETURN":? :NEXT N:SOUND 0,0,0,0:? :? "POKE 842,12:CONT":POSITION 2,0:POKE 842,13:STOP
31115 GRAPHICS 12:POKE 559,0:DL=PEEK(560)+PEEK(561)*256:EKR=PEEK(88)+PEEK(89)*256:POKE DL+3,PEEK(DL+3)-2:POKE 710,0
31116 DL2L=PEEK(DL+26):DL2H=PEEK(DL+27):FOR I=DL+6 TO DL+24:POKE I,PEEK(I)-2:NEXT I:POKE DL+26,DL2L-71:POKE DL+27,DL2H-1
31117 RESTORE 32000:FNT=DL2L+DL2H*256+64:TRAP 31120
31118 READ A,B,C,D,E,F,G,H:POKE FNT+0,A:POKE FNT+1,B:POKE FNT+2,C:POKE FNT+3,D:POKE FNT+4,E:POKE FNT+5,F:POKE FNT+6,G
31119 POKE FNT+7,H:FNT=FNT+8:GOTO 31118
31120 X=0:Y=19:XD=0.9:YD=-0.33:C=0:POKE 559,34:POKE 756,DL2H-1
31121 GOSUB 31220+C:COLOR 108+C:PLOT 0,Y:DRAWTO X,19:C=C+1:IF C>3 THEN C=0
31130 X=X+XD:IF X>38 THEN X=39
31131 IF X>1 THEN GOTO (31140+C)
31132 GOTO 31150
31140 POSITION X-1,18:? #6;"ab";:POSITION X-1,19:? #6;"cd";:GOTO 31150
31141 POSITION X-1,18:? #6;"ef";:POSITION X-1,19:? #6;"gh";:GOTO 31150
31142 POSITION X-1,18:? #6;"ij";:POSITION X-1,19:? #6;"kl";:GOTO 31150
31143 REM
31150 Y=Y+YD:IF Y>0 THEN 31121
31160 X=0:Y=18:C=0
31170 GOSUB 31220+C:COLOR 108+C:PLOT X,0:DRAWTO 39,Y:C=C+1:IF C>3 THEN C=0
31180 X=X+XD:IF X>38 THEN X=39
31190 Y=Y+YD:IF Y>0 THEN 31170
31200 FOR I=0 TO 1000:FOR N=0 TO 3:GOSUB (31220+N)
31210 NEXT N:NEXT I
31219 REM LINIE DYNAMICZNE
31220 POKE 656,0:POKE 657,0:? "¯Š3ÇÊQ0¶Þ@µõm‚ŽsØfŒÕƒD3ÏÆ4GY÷콶gK";:RETURN
31221 POKE 656,0:POKE 657,0:? "–õPÌV{ êÚ$‹¿¦èGŒð¾hJESJçñM©?|pÐá5–À";:RETURN
31222 POKE 656,0:POKE 657,0:? "±Á½ù¦ƒ²Ï@z\t÷K©Mã\c81¥$8¯V.¯uLÕ†ñÊY";:RETURN
31223 POKE 656,0:POKE 657,0:? "8h´—]ÑÄéA„µ«Kúå=còÁå_me”{À×s¼LãÆâ";:RETURN
31230 GOTO 31200
31999 RETURN (zabójcę silnika magnetofonu/albo i PIA/ od BCA musiałem usunąć/zamieniłem na SOUNDa - nie chcielibyśmy mieć na sumieniu czyjejś atarynki)
Linie DATA
32000 DATA 0,0,0,0,16,16,16,38
32001 DATA 0,0,0,0,3,3,0,3
32002 DATA 0,0,0,0,0,0,0,112
32003 DATA 0,0,0,0,0,0,0,11
32004 DATA 0,0,0,0,24,22,63,254
32005 DATA 0,7,55,6,14,52,4,0
32006 DATA 63,253,248,126,5,4,2,0
32007 DATA 0,0,0,0,1,0,0,0
32008 DATA 19,127,63,231,64,128,128,0
32009 DATA 248,216,192,224,152,200,64,0
32010 DATA 31,11,3,1,0,0,0,0
32011 DATA 252,252,56,184,104,168,0,0,"TRAP"Załącznik z PECETOWYM kodowaniem końca linii, otwarcie: emulator, dodaj urządzenie - dysk H:, zamapuj folder z plikiem (koniecznie z długimi nazwami!), załaduj:
E."H6:PA2025_START.LST"
Oczywiście MAW! dobrze że wywaliłeś POKE 54018 choć to prima aprilis
Nadmierne Pokowanie może wywoływać skutki uboczne.
TODO: skrócić nazwy plików. *.LST
Nie chodzi o nadmierne pokowanie, a o to, co kryje się za wielokrotnym użyciem 54018 - posiłkowałem się tym:
Rzeczywiste uruchomienie silnika nastąpi, gdy na bazie tranzystora Q2 pojawi się napięcie +5V doprowadzone tam z pinu 8 gniazda SIO. Pin 8 to MOTOR CONTROL. Linią tą steruje tranzystor Q7, znajdujący się na płycie Atari, z kolei tranzystor Q7 sterowany jest przez układ PIA 6520, poprzez jego pin 39 opisany jako CA2. Wydanie polecenia POKE 54018,52 otwiera tranzystor Q7, Q2 i Q1. Silnik kręci. Natomiast POKE 54018,60 blokuje całość i silnik nie kręci pomimo włączenia klawisza PLAY.
Lepiej dmuchać na zimne - jeszcze ktoś odpali PA'25 na real Atari i kto wie, co wywoła taki stresstest (200 przełączeń co mniej niż sekunda) na PIA i linię tranzystorową...
Z lekkim poślizgiem, ale chyba czas zamknąć. Prosiłbym, jeśli jest coś jeszcze do dokończenia, o wprowadzenie ostatnich poprawek i wygenerowanie jednego finalnego pliku - nie chciałbym przez nieuwagę wyrzucić czyjegoś kodu.
Niestety żałuję, ale nie dane mi było pouczestniczyć - a taka data jest! Może w następnym roku?
Dziękuję wszystkim za wkład i uczestnictwo.
Szkoda, że nie miałeś okazji dodać swojego :(
Finalny kod (niestety, jeszcze z paroma błędami):
(ciach! idź do ostatniego postu, gdzie znajdziesz właściwy zdebugowany plik!)Dzięki wszystkim za uczestnictwo, zwłaszcza Mono za pamiętanie o compo!
PS. przydała by się dogrywka :-)
Ja również bardzo dziękuję za tegoroczne compo! W ramach prima-aprylisowego żartu, w tym roku napisałem do compo zerolinijkowiec, ale nikt tego nawet niestety nie zauważył i nie docenił:-(
:-)
PS. Pozdrowienia dla wszystkich, może w przyszłym roku się znowu załapię jak w niektórych poprzednich latach:-)
@Mq: Ależ zostałeś dopisany instrukcją REM w trybie bezpośrednim, która automatycznie otrzymuje numer 32768.
REM MqTak więc pełno Cię, a jakby nikogo nie było.
Hahaha:-) Dzięki:-)
Poniżej zdebugowania wersja, która zapewnia właściwe wrażenia estatyczne :-)
1 GOSUB 32600
2 GOSUB 31100
3 GOSUB 31000
11111 END
31000 REM 31000 - OUTRO
31001 GRAPHICS 0:? "It's all, Folks!":? " See you at the next Prima Aprilis Compo!"
31099 RETURN
31100 REM 31100 - LOADING SCREEN, INTRODUCTION
31101 REM SOME INFO BEFORE DEMO MODE AND LOADING SCREEN BY MAW
31102 E=24:L=E-1:W=25:ED=52:DIM BE$(E):BE$="BOOT ERROR ":DIM PA25$(E):PA25$="PRIMA APRILIS COMPO 2025"
31103 POKE 82,2:FOR I=0 TO W:? CHR$(125):? BE$:? "be patient..."
31104 SOUND 0,8,ED,10:ED=ED+(ED=52)*8-(ED=60)*8:NEXT I:POKE 752,1:? CHR$(125)
31105 SOUND 0,12,ED,10:ED=ED+8:IF ED=68 THEN ED=52:REM BCA #ORYGINAL MOGL ZABIC PIA/KOREKTA MAW
31106 ? CHR$(93* NOT (INT(RND(0)*5))+32):IF E=0 THEN W=W-1:IF W=0 THEN POKE 54018,60:GRAPHICS 0:GOTO 31110:REM MAGNET STOP BY BCA
31107 POSITION RND(0)*12,PEEK(84):? BE$:LL=L*RND(0)+1:IF PA25$(LL,LL)="*" THEN 31105
31108 BE$(LL,LL)=CHR$(128+ASC(PA25$(LL,LL))):PA25$(LL,LL)="*":E=E-1:GOTO 31105
31110 POKE 82,2:POSITION 2,1:? "READY":POKE 694,128:? "AI GOT YOUR ATARI!!!";CHR$(253):POKE 622,1:POKE 752,1
31111 POKE 82,0:POKE 694,0:POSITION 0,23:FOR N=40 TO 43:? 312;N;" ? ";CHR$(34);:FOR I=0 TO 38
31112 Z0=124*RND(0):IF (Z0>26 AND Z0<35) THEN 31112
31113 Z0=Z0+INT(RND(0)*2)*128:SOUND 0,Z0,10,10:? CHR$(Z0);:NEXT I
31114 ? CHR$(34);";:RET.":? :NEXT N:SOUND 0,0,0,0:? :? "POKE 842,12:CONT":POKE 622,0:POSITION 2,0:POKE 842,13:STOP
31115 GRAPHICS 12:POKE 559,0:DL=PEEK(560)+PEEK(561)*256:POKE DL+3,66:POKE DL+4,0:POKE DL+5,128:POKE 710,0:TRAP 31120
31116 DL2L=PEEK(DL+26):DL2H=PEEK(DL+27):FOR I=DL+6 TO DL+24:POKE I,2:NEXT I:POKE DL+26,128:POKE DL+27,130
31117 POKE 88,0:POKE 89,128:COLOR 32:FOR I=0 TO 23:PLOT 0,I:DRAWTO 39,I:NEXT I:RESTORE 32000:FNT=DL2L+DL2H*256+40
31118 READ A,B,C,D,E,F,G,H:POKE FNT+0,A:POKE FNT+1,B:POKE FNT+2,C:POKE FNT+3,D
31119 POKE FNT+4,E:POKE FNT+5,F:POKE FNT+6,G:POKE FNT+7,H:FNT=FNT+8:GOTO 31118
31120 X=0:Y=19:XD=0.9:YD=-0.33:C=108:N=31140:POKE 559,34:POKE 752,0:POKE 756,INT(DL2H/4)*4
31121 POKE 656,0:POKE 657,0:GOSUB N+100
31130 POKE 200,C:PLOT 0,Y:DRAWTO X,19:C=C+1:IF C>112 THEN C=108
31131 X=X+XD:IF X>38 THEN X=39
31132 GOTO N
31140 POSITION X,18:? #6;"qr";:POSITION X,19:? #6;"st";:GOTO 31145
31141 POSITION X,18:? #6;"uv";:POSITION X,19:? #6;"wx";:GOTO 31145
31142 POSITION X,18:? #6;"yz";:POSITION X,19:? #6;"{|";:GOTO 31145
31143 POSITION X,18:? #6;"uv";:POSITION X,19:? #6;"gh";
31145 N=N+1:IF N>31143 THEN N=31140
31150 Y=Y+YD:IF Y>0 THEN 31121
31160 X=0:Y=18:C=108:N=31240
31170 POKE 656,0:POKE 657,0:GOSUB N:N=N+1:IF N>31243 THEN N=31240
31171 POKE 200,C:PLOT X,0:DRAWTO 39,Y:C=C+1:IF C>112 THEN C=108
31180 X=X+XD:IF X>38 THEN X=39
31190 Y=Y+YD:IF Y>0 THEN 31170
31200 POKE 200,107:FOR I=0 TO 255
31201 FOR N=31240 TO 31243:POKE 656,0:POKE 657,0:GOSUB N
31205 RR=32020+RND(0)*56:RESTORE RR:READ X,Y,D
31206 IF D>0 THEN PLOT X,Y:DRAWTO X+D,Y
31207 IF D<0 THEN PLOT X,Y:DRAWTO X,Y-D
31218 NEXT N:NEXT I
31219 REM LINIE DYNAMICZNE
31299 RETURN
31999 RETURN
POKE DL+4,0:POKE DL+5,128
32000 DATA 0,0,0,4,28,14,15,0
32001 DATA 0,0,0,0,16,56,144,166
32002 DATA 0,7,55,6,14,52,4,0
32003 DATA 63,253,248,126,5,4,2,0
32004 DATA 0,0,0,0,0,30,3,0
32005 DATA 0,0,0,0,64,224,0,220
32006 DATA 4,31,15,57,80,32,32,0
32007 DATA 254,246,240,248,38,50,16,0
32008 DATA 0,0,0,0,12,6,3,0
32009 DATA 0,0,0,0,16,56,150,63
32010 DATA 11,23,35,35,1,0,0,0
32011 DATA 253,248,248,40,176,96,0,0
32012 DATA "END"
32020 DATA 11,0,3
32021 DATA 24,0,3
32022 DATA 11,1,-3
32023 DATA 27,1,-3
32024 DATA 12,1,14
32025 DATA 12,2,-2
32026 DATA 26,2,-2
32027 DATA 13,2,-2
32028 DATA 25,2,-2
32029 DATA 2,6,7
32030 DATA 28,6,7
32031 DATA 14,2,-2
32032 DATA 24,2,-2
32033 DATA 15,2,8
32034 DATA 15,3,8
32035 DATA 15,4,8
32036 DATA 10,6,17
32037 DATA 10,7,-4
32038 DATA 27,7,-4
32039 DATA 11,8,5
32040 DATA 21,8,5
32041 DATA 11,9,1
32042 DATA 15,9,1
32043 DATA 17,9,3
32044 DATA 21,9,1
32045 DATA 25,9,1
32046 DATA 17,10,3
32047 DATA 11,10,-2
32048 DATA 26,10,-2
32049 DATA 12,11,-2
32050 DATA 25,11,-2
32051 DATA 16,11,5
32052 DATA 13,12,4
32053 DATA 20,12,4
32054 DATA 13,13,3
32055 DATA 21,13,3
32056 DATA 11,15,-1
32057 DATA 26,15,-1
32058 DATA 18,14,1
32059 DATA 15,15,7
32060 DATA 15,16,7
32061 DATA 15,17,7
32062 DATA 15,18,7
32063 DATA 12,16,-2
32064 DATA 25,16,-2
32065 DATA 13,16,-3
32066 DATA 24,16,-3
32067 DATA 14,16,-4
32068 DATA 23,16,-4
32069 DATA 15,19,-2
32070 DATA 22,19,-2
32071 DATA 16,19,5
32072 DATA 16,20,5
32073 DATA 16,21,5
32074 DATA 16,22,2
32075 DATA 19,22,2
32076 DATA 18,23,2
32599 RETURN
32600 REM 32600 - BLOKI INICJACYJNE
32601 GRAPHICS 8:POKE 106,128:GRAPHICS 8:GRAPHICS 0:POKE 82,0
32699 RETURN
32700 REM ****************************
32701 REM * PRIMA APRILIS COMPO 2025 *
32702 REM ****************************
32703 REM BY MONO,PABLOZ,MAW,BCA
32704 REM ATARI JEST LEPSZE OD ZX TRUMNY
32705 REM JEDZIEMY OD KONCA BASICA PANOWIE(I PANIE)
32706 REM 32600 - REZERWACJA PAMIECI (WSPOLNA DLA WSZYSTKICH) - OBNIZ RAMTOP, ZAKLNIJ DUCHY
32707 REM 32000 - REZERWACJA BLOKU LINII DLA DATA
32708 REM 31100 - LOADING SCREEN, INTRODUCTION
32709 REM 31000 - ...
32766 RETURN :REM NIE ZAPOMNIEC O POKE 82,0!!!
RUN(wersję niezdebugowaną usunąłem, żeby nie mylić pobierających)
Strony 1
Zaloguj się lub zarejestruj by napisać odpowiedź
atari.area forum » Różne » Prima Aprilis Compo 2025
Wygenerowano w 0.024 sekund, wykonano 62 zapytań