0 REM PRIMA-APRILIS 2014
1 REM BY SIKOR, SOME MODS IN SIKOR CODE DONE BY SEBAN :)
10 POKE 622,1:POKE 82,0:GRAPHICS 0:POKE 710,0:POKE 709,15:POKE 752,1:POSITION 0,11
11 ? "TO NIE JEST DEMO DLA NORMALNYCH LUDZI...":? "TO JEST [PRIMA APRILIS 2014 DEMO]..."
12 N=128:GOSUB 1005
14 REM ------------------------------
15 REM -- SEBAN CODE STARTS HERE :)
16 FOR I=0 TO 15:POKE 712,I:POKE 710,I:POKE 709,15-I:GOSUB 1000:NEXT I:FOR I=1 TO 23:? :NEXT I:POSITION 0,0
17 FOR I=1 TO 959:? CHR$(6+RND(1));:NEXT I:FOR I=2 TO 38:POSITION I,5:? CHR$(18):POSITION I,19:? CHR$(18):NEXT I
18 FOR I=5 TO 19:POSITION 2,I:? CHR$(124):POSITION 38,I:? CHR$(124):NEXT I:POKE 82,3:POKE 83,38
19 POSITION 3,6:FOR I=1 TO 13:? "                                   ":NEXT I:DIM A$(512),B$(256)
20 A$="                                  TO JEST SUPER FAST TEXT MODE SINUS SCROLLER... "
22 A$(LEN(A$))="                                  "
23 DEG :FOR I=1 TO 40:B$(I,I)=CHR$(10):NEXT I
25 FOR I=1 TO LEN(A$)-37:POKE 77,0
26 FOR J=4 TO 36:Y=12+SIN(P)*5
27 POSITION J,ASC(B$(J,J)):? " ";
28 POSITION J,Y:? A$(I+J,I+J)
29 B$(J,J)=CHR$(Y)
30 P=P+10:NEXT J:NEXT I
31 FOR I=0 TO 15:POKE 712,15-I:POKE 710,15-I:GOSUB 1000:NEXT I:POKE 82,2:POKE 83,39:POKE 622,0:? CHR$(125)
32 POKE 709,15:? "TIME FOR NEXT PART..."
33 REM -- SEBAN CODE ENDS HERE ;) --
34 REM ------------------------------
99 GOTO 99
998 POKE 622,0:POKE 82,2:POKE 752,1:GRAPHICS 0:END 
999 REM - SOME SUBROUTINES BY SEBAN :)
1000 REM -- PAUSE FOR 1-FRAME --
1001 POKE 20,0
1002 IF PEEK(20)=0 THEN 1002
1003 RETURN 
1004 REM -- WAIT *N OF FRAMES --
1005 POKE 20,0
1006 IF PEEK(20)<N THEN 1006
1007 RETURN 

0 REM PRIMA-APRILIS 2014
1 REM BY SIKOR, SOME MODS IN SIKOR CODE DONE BY SEBAN :)
10 POKE 622,1:POKE 82,0:GRAPHICS 0:POKE 710,0:POKE 709,15:POKE 752,1:POSITION 0,11
11 ? "TO NIE JEST DEMO DLA NORMALNYCH LUDZI...":? "TO JEST [PRIMA APRILIS 2014 DEMO]..."
12 DEG :FOR I=0 TO 255:POKE 1536+I,12+5*SIN(I*1.4):POKE 40000,PEEK(1536+I)+9:NEXT I:POKE 40000,0
14 REM ------------------------------
15 REM -- SEBAN CODE STARTS HERE :)
16 FOR I=0 TO 15:POKE 712,I:POKE 710,I:POKE 709,15-I:GOSUB 1000:NEXT I:FOR I=1 TO 23:? :NEXT I:POSITION 0,0
17 FOR I=1 TO 959:? CHR$(6+RND(1));:NEXT I:FOR I=2 TO 38:POSITION I,5:? CHR$(18):POSITION I,19:? CHR$(18):NEXT I
18 FOR I=5 TO 19:POSITION 2,I:? CHR$(124):POSITION 38,I:? CHR$(124):NEXT I:POKE 82,3:POKE 83,38
19 POSITION 3,6:FOR I=1 TO 13:? "                                   ":NEXT I:DIM A$(512),B$(256)
20 A$="                                  TO JEST SUPER FAST TEXT MODE SINUS SCROLLER... "
22 A$(LEN(A$))="                                  "
23 FOR I=1 TO 40:B$(I,I)=CHR$(10):NEXT I:E=LEN(A$)-37:Q=0
25 FOR I=1 TO E:P=Q:FOR J=4 TO 36
26 K=I+J:Y=PEEK(1536+P)
27 POSITION J,ASC(B$(J,J)):? " ";
28 POSITION J,Y:? A$(K,K)
29 B$(J,J)=CHR$(Y)
30 P=P+8:IF P>255 THEN P=P-256
31 NEXT J:Q=Q+16:IF Q>255 THEN Q=0
32 NEXT I
33 FOR I=0 TO 15:POKE 712,15-I:POKE 710,15-I:GOSUB 1000:NEXT I:POKE 82,2:POKE 83,39:POKE 622,0:? CHR$(125)
34 POKE 709,15:? "TIME FOR NEXT PART..."
35 REM -- SEBAN CODE ENDS HERE ;) --
36 REM ------------------------------
99 GOTO 99
998 POKE 622,0:POKE 82,2:POKE 752,1:GRAPHICS 0:END 
999 REM - SOME SUBROUTINES BY SEBAN :)
1000 REM -- PAUSE FOR 1-FRAME --
1001 POKE 20,0
1002 IF PEEK(20)=0 THEN 1002
1003 RETURN 
1004 REM -- WAIT *N OF FRAMES --
1005 POKE 20,0
1006 IF PEEK(20)<N THEN 1006
1007 RETURN