hahahaha! Vasco jesteś the best :) tylko czekałem na tę chwilę kiedy ktoś zapyta czy uwzględniałem "spalone" w trakcie gry :D i muszę Cię zmartwić... ponieważ żaden ze mnie kibic, to niestety ignorowaliśmy sytuację w których następowały spalone :)
A tak przy okazji dzisiejszej wieczornej sesji programowania w Atari BASIC powstało coś o roboczej nazwie "zjadacz", młody oczywiście sugerował się Pacman-em, jednak z oryginałem ma to niewiele wspólnego... chociaż dziś można było mieć wpływ na rozgrywkę i to była największa frajda tego wieczoru ;D
10 GRAPHICS 0:POKE 752,1:? :POKE 77,0
11 POKE 710,192:GOSUB 100:GOSUB 115
12 S=STICK(0):T=STRIG(0)
13 X=20:Y=12:OX=X:OY=Y
15 S=STICK(0):T=STRIG(0)
16 IF S=7 THEN IF X<38 THEN X=X+1
17 IF S=11 THEN IF X>1 THEN X=X-1
18 IF S=13 THEN IF Y<22 THEN Y=Y+1
19 IF S=14 THEN IF Y>1 THEN Y=Y-1
29 LOCATE X,Y,C:IF C=20 THEN GOSUB 110
30 COLOR 60:PLOT X,Y
31 IF OX<>X OR OY<>Y THEN COLOR 32:PLOT OX,OY
32 OX=X:OY=Y
33 GOSUB 120
49 IF K<20 THEN GOTO 15
50 ? CHR$(125):POKE 710,96
51 ? :? "TWOJ WYNIK TO ";W;" PUNKTOW"
52 ? :? "TWOJ CZAS TO ";INT(TIME/50);" SEKUND"
53 SOUND 0,255,10,10:SOUND 1,254,10,10
54 ? :? "NACISNIJ FIRE ABY ZAGRAC OD NOWA"
55 IF STRIG(0) THEN 55
56 SOUND 0,0,0,0:SOUND 1,0,0,0
57 IF STRIG(0)=0 THEN 57
99 RUN
100 REM --- PROCEDURY ---
101 COLOR 20
102 FOR I=1 TO 20
103 X=RND(0)*37+1
104 Y=RND(0)*21+1
105 IF X=20 AND Y=12 THEN 103
106 LOCATE X,Y,C:IF C=20 THEN 103
107 PLOT X,Y:NEXT I:K=0
108 POKE 18,0:POKE 19,0:POKE 20,0
109 RETURN
110 REM --- ZJEDZENIE KROPKI ---
111 W=W+INT(1000/(TIME-OTIME))
112 FOR I=0 TO 255 STEP 32:SOUND 0,I,10,15:NEXT I:SOUND 0,0,0,0
113 K=K+1:OTIME=TIME
115 POSITION 0,0:? "WYNIK: ",W
116 RETURN
120 REM --- CZAS ---
121 TIME=PEEK(20)+256*PEEK(19)+65536*PEEK(18)
122 POSITION 20,0:? "CZAS:",INT(TIME/50)
123 RETURN
